VisionFive - Mender - Yocto

Wir nutzen den Yocto-Kirkstone-Zweig für die Entwicklung. Wir gehen davon aus, dass Sie bereits eine funktionierende Entwicklungsumgebung installiert und Ihre Umgebung wie in VisionFive - Mender - Yocto - Teil 1 beschrieben eingerichtet haben.

Mender-Server-Einrichtung

Die Installation des Mender-Servers wird in dieser Artikelreihe nicht behandelt. Für unsere Testumgebung haben wir den Mender-Server mithilfe des Installations-Tutorials mit Docker Compose installiert, wie in Installation mit Docker Compose beschrieben.

Bevor Sie fortfahren, sollten Sie sich ohne jegliche Fehlermeldungen beim Mender-Server anmelden können.

Klonen von meta-mender

Gehen Sie zu Ihrem Poky-Verzeichnis – in meinem Fall poky-kirkstone – und klonen Sie das Repository meta-mender. Da es noch keinen Kirkstone-Zweig gibt, müssen Sie den Zweig „master-next“ klonen.

cd poky-kirkstone
git clone -b master-next https://github.com/mendersoftware/meta-mender.git

local.conf und bblayers.conf

Kopieren Sie bblayers.conf.sample-mender und local.conf.sample-mender aus dem Verzeichnis meta-interelectronix-visionfive in das Verzeichnis conf und benennen Sie in bblayers.conf und local.conf um:

cp ../poky-kirkstone/meta-interelectronix-visionfive/conf/bblayers.conf.sample-mender conf/bblayers.conf
cp ../poky-kirkstone/meta-interelectronix-visionfive/conf/local.conf.sample-mender conf/local.conf

In der Datei bblayers.conf müssen Sie den Pfad zu Ihrem Verzeichnis poky-kirkstone anpassen. Löschen Sie auch die Zeile „/workdir/poky-kirkstone/meta-interelectronix\“ – sie wird nur für unsere Anpassung von psplash benötigt.

Die wichtigen Einstellungen in local.conf sind:

# mender settings
# The name of the disk image and Artifact that will be built.
# This is what the device will report that it is running, and different updates must have different names
# because Mender will skip installation of an Artifact if it is already installed.
MENDER_ARTIFACT_NAME = "release-1"

INHERIT += "mender-full"

# The version of Mender to build. This needs to match an existing recipe in the meta-mender repository.
#
# Given your Yocto Project version, see which versions of Mender you can currently build here:
# https://docs.mender.io/overview/compatibility#mender-client-and-yocto-project-version
#
# Given a Mender client version, see the corresponding version of the mender-artifact utility:
# https://docs.mender.io/overview/compatibility#mender-clientserver-and-artifact-format
#
# By default this will select the latest version of the tools that is backwards compatible with the
# given Yocto branch.
# If you need an earlier version, or a later version even though it may not be backwards compatible,
# please uncomment the following and set to the required version. If you want to use the bleeding
# edge version, specify "master-git%", but keep in mind that these versions may not be stable:
#
# PREFERRED_VERSION_mender-client = "3.3.0"
# PREFERRED_VERSION_mender-artifact = "3.8.0"
# PREFERRED_VERSION_mender-artifact-native = "3.8.0"
# PREFERRED_VERSION_mender-connect = "2.0.1"

# The following settings to enable systemd are needed for all Yocto
# releases sumo and older.  Newer releases have these settings conditionally
# based on the MENDER_FEATURES settings and the inherit of mender-full above.
DISTRO_FEATURES:append = " systemd"
VIRTUAL-RUNTIME:init_manager = "systemd"
DISTRO_FEATURES_BACKFILL_CONSIDERED = "sysvinit"
VIRTUAL-RUNTIME_initscripts = ""

ARTIFACTIMG_FSTYPE = "ext4"

# Example: Memory card storage
MENDER_STORAGE_DEVICE = "/dev/mmcblk0"
# Example: Memory card with 2GiB of storage.
#MENDER_STORAGE_TOTAL_SIZE_MB = "29476"
#MENDER_STORAGE_TOTAL_SIZE_MB = "14738"
MENDER_STORAGE_TOTAL_SIZE_MB = "7369"

MENDER_UBOOT_STORAGE_INTERFACE = "mmc"
MENDER_UBOOT_STORAGE_DEVICE = "0"

MENDER_BOOT_PART = "${MENDER_STORAGE_DEVICE_BASE}1"
MENDER_DATA_PART = "${MENDER_STORAGE_DEVICE_BASE}4"
MENDER_ROOTFS_PART_A = "${MENDER_STORAGE_DEVICE_BASE}2"
MENDER_ROOTFS_PART_B = "${MENDER_STORAGE_DEVICE_BASE}3"

MENDER_FEATURES_ENABLE:append = " mender-uboot mender-image-sd"
MENDER_FEATURES_DISABLE:append = " mender-grub mender-image-uefi"

MACHINE_ESSENTIAL_EXTRA_RDEPENDS:append = " kernel-image kernel-devicetree"

PREFERRED_VERSION:mender-client = "3.3.0"

Anpassung von meta-starfive-bsp

Sie sollten einen Zweig von meta-starfive-bsp erstellen, um die für die Mender-Einrichtung erforderlichen Einstellungen zu ergänzen.

Anpassungen sind erforderlich in:

• conf/machine/starfive-visionfive-jh7100.conf: Entfernen oder kommentieren Sie diese beiden Zeilen

UBOOT_ENV ?= "uEnv"
UBOOT_ENV_SUFFIX = "txt"

• recipes-bsp/bootfiles/files/uEnv.txt: Ersetzen Sie die folgende Zeile, damit die Mender-Variablen beim Booten berücksichtigt werden

bootcmd=load mmc 0:1 ${kernel_addr_r} @IMAGETYPE@; load mmc 0:1 ${fdt_addr_r} jh7100-starfive-visionfive-v1.dtb; setenv bootargs 'root=${mender_kernel_root} rw rootfstype=ext4 rootwait earlycon console=ttyS0,115200n8'; booti ${kernel_addr_r} - ${fdt_addr_r}

• recipes-bsp/u-boot/u-boot-visionfive_v2022.03.bb: Fügen Sie die folgenden Zeilen hinzu. So wird meta-mender mitgeteilt, dass U-Boot individuell genutzt wird

require recipes-bsp/u-boot/u-boot-mender.inc

PROVIDES += "u-boot"
RPROVIDES_${PN} += "u-boot"

BOOT_FILES:append = " uEnv.txt"

Recipe in meta-interelectronix-visionfive

Manche Einstellungen und Variablen müssen in Ihrem individuellen Meta-Layer festgelegt werden, wie wir es bei meta-interelectronix-visionfive tun.

• recipes-mender/mender-client/mender-client_%.bbappend: Fügen Sie die URL des Mender-Servers hinzu

MENDER_SERVER_URL = "https://mender.interelectronix.com"

• recipes-bsp/u-boot/u-boot-visionfive_%.bbappend: Fügen Sie die folgenden Zeilen hinzu

MENDER_UBOOT_AUTO_CONFIGURE = "1"
BOOTENV_SIZE = "0x20000"

• recipes-bsp/u-boot-env/*: Fügen Sie dieses Recipe aus der heruntergeladenen ZIP-Datei hinzu. Es enthält zwei uEnv-Dateien, die im Root-Dateisystem genutzt werden. uEnv_visionfive.txt wird in rootfs verwendet, wenn von Partition A gebootet wird, während uEnv_visionfive3.txt beim Booten von Partition B genutzt wird.

• recipes-core/images/vision-five-image-mender.bb: Nehmen Sie dieses Image-Recipe oder fügen Sie „u-boot-env“ zu Ihrem Image-Recipe hinzu

IMAGE_INSTALL:append = " v4l-utils u-boot-env"

Erfahren Sie, wie man U-Boot für Mender einrichtet in VisionFive - Mender - Yocto - Teil 3.

Copyright © 2022 Interelectronix e.K.
Dieser Projekt-Quellcode ist unter der GPL-3.0 Lizenz lizenziert.