VisionFive - Mender - Yocto

हम डेवलपमेंट के लिए Yocto Kirkstone ब्रांच का इस्तेमाल कर रहे हैं। हम यह मानकर चल रहे हैं कि आपके पास पहले से ही एक कार्यशील डेवलपमेंट परिवेश इंस्टॉल किया हुआ है और आपने VisionFive - Mender - Yocto - भाग 1 में बताए गए तरीके से अपना परिवेश सेट अप कर लिया है।

Mender सर्वर का सेटअप

Mender सर्वर का इंस्टॉलेशन इस लेख श्रृंखला का हिस्सा नहीं है। अपने टेस्ट परिवेश के लिए, हमने Docker Compose के साथ इंस्टॉलेशन में बताए गए docker-compose के इंस्टॉलेशन ट्यूटोरियल का इस्तेमाल करके Mender सर्वर इंस्टॉल किया है।

जारी रखने से पहले, आप Mender सर्वर में लॉग इन कर सकेंगे और आपको गड़बड़ी का कोई भी मैसेज दिखाई नहीं देगा।

meta-mender को क्लोन करें

अपनी poky डायरेक्टरी पर जाएँ - मेरे मामले में यह poky-kirkstone है - और फिर meta-mender रिपॉज़िटरी को क्लोन करें। चूँकि यहाँ अब तक कोई Kirkstone ब्रांच नहीं है, इसलिए आपको 'master-next' ब्रांच को क्लोन करना होगा।

cd poky-kirkstone
git clone -b master-next https://github.com/mendersoftware/meta-mender.git

local.conf और bblayers.conf

meta-interelectronix-visionfive डायरेक्टरी से bblayers.conf.sample-mender और local.conf.sample-mender को conf डायरेक्टरी में कॉपी करें और उसका नाम बदलकर bblayers.conf और local.conf कर दें:

cp ../poky-kirkstone/meta-interelectronix-visionfive/conf/bblayers.conf.sample-mender conf/bblayers.conf
cp ../poky-kirkstone/meta-interelectronix-visionfive/conf/local.conf.sample-mender conf/local.conf

bblayers.conf फ़ाइल में आपको अपनी poky-kirkstone डायरेक्टरी तक ले जाने वाले पाथ में ज़रूरत के मुताबिक बदलाव करना होगा। साथ ही '/workdir/poky-kirkstone/meta-interelectronix ' लाइन को भी मिटा दें - इसकी ज़रूरत सिर्फ़ हमारे psplash कस्टमाइज़ेशन के लिए पड़ती है।

local.conf की महत्त्वपूर्ण सेटिंग इस प्रकार हैं:

# mender settings
# The name of the disk image and Artifact that will be built.
# This is what the device will report that it is running, and different updates must have different names
# because Mender will skip installation of an Artifact if it is already installed.
MENDER_ARTIFACT_NAME = "release-1"

INHERIT += "mender-full"

# The version of Mender to build. This needs to match an existing recipe in the meta-mender repository.
#
# Given your Yocto Project version, see which versions of Mender you can currently build here:
# https://docs.mender.io/overview/compatibility#mender-client-and-yocto-project-version
#
# Given a Mender client version, see the corresponding version of the mender-artifact utility:
# https://docs.mender.io/overview/compatibility#mender-clientserver-and-artifact-format
#
# By default this will select the latest version of the tools that is backwards compatible with the
# given Yocto branch.
# If you need an earlier version, or a later version even though it may not be backwards compatible,
# please uncomment the following and set to the required version. If you want to use the bleeding
# edge version, specify "master-git%", but keep in mind that these versions may not be stable:
#
# PREFERRED_VERSION_mender-client = "3.3.0"
# PREFERRED_VERSION_mender-artifact = "3.8.0"
# PREFERRED_VERSION_mender-artifact-native = "3.8.0"
# PREFERRED_VERSION_mender-connect = "2.0.1"

# The following settings to enable systemd are needed for all Yocto
# releases sumo and older.  Newer releases have these settings conditionally
# based on the MENDER_FEATURES settings and the inherit of mender-full above.
DISTRO_FEATURES:append = " systemd"
VIRTUAL-RUNTIME:init_manager = "systemd"
DISTRO_FEATURES_BACKFILL_CONSIDERED = "sysvinit"
VIRTUAL-RUNTIME_initscripts = ""

ARTIFACTIMG_FSTYPE = "ext4"

# Example: Memory card storage
MENDER_STORAGE_DEVICE = "/dev/mmcblk0"
# Example: Memory card with 2GiB of storage.
#MENDER_STORAGE_TOTAL_SIZE_MB = "29476"
#MENDER_STORAGE_TOTAL_SIZE_MB = "14738"
MENDER_STORAGE_TOTAL_SIZE_MB = "7369"

MENDER_UBOOT_STORAGE_INTERFACE = "mmc"
MENDER_UBOOT_STORAGE_DEVICE = "0"

MENDER_BOOT_PART = "${MENDER_STORAGE_DEVICE_BASE}1"
MENDER_DATA_PART = "${MENDER_STORAGE_DEVICE_BASE}4"
MENDER_ROOTFS_PART_A = "${MENDER_STORAGE_DEVICE_BASE}2"
MENDER_ROOTFS_PART_B = "${MENDER_STORAGE_DEVICE_BASE}3"

MENDER_FEATURES_ENABLE:append = " mender-uboot mender-image-sd"
MENDER_FEATURES_DISABLE:append = " mender-grub mender-image-uefi"

MACHINE_ESSENTIAL_EXTRA_RDEPENDS:append = " kernel-image kernel-devicetree"

PREFERRED_VERSION:mender-client = "3.3.0"

meta-starfive-bsp को कस्टमाइज़ करें

Mender सेटअप के लिए ज़रूरी सेटिंग जोड़ने के लिए आपको meta-starfive-bsp का ब्रांच बनाना होगा।

कस्टमाइज़ेशन की ज़रूरत इनमें पड़ती है:

• conf/machine/starfive-visionfive-jh7100.conf: इन दो लाइनों को हटाएँ या कमेंट करें

UBOOT_ENV ?= "uEnv"
UBOOT_ENV_SUFFIX = "txt"

• recipes-bsp/bootfiles/files/uEnv.txt: बूटिंग के दौरान इस लाइन को हटाकर Mender वेरिएबल शामिल करें

bootcmd=load mmc 0:1 ${kernel_addr_r} @IMAGETYPE@; load mmc 0:1 ${fdt_addr_r} jh7100-starfive-visionfive-v1.dtb; setenv bootargs 'root=${mender_kernel_root} rw rootfstype=ext4 rootwait earlycon console=ttyS0,115200n8'; booti ${kernel_addr_r} - ${fdt_addr_r}

• recipes-bsp/u-boot/u-boot-visionfive_v2022.03.bb: नीचे दी गई लाइनों को शामिल करके meta-mender को बताएँ कि एक कस्टम u-boot का इस्तेमाल किया गया है

require recipes-bsp/u-boot/u-boot-mender.inc

PROVIDES += "u-boot"
RPROVIDES_${PN} += "u-boot"

BOOT_FILES:append = " uEnv.txt"

meta-interelectronix-visionfive में मौजूद रेसिपी

कस्टम मेटा-लेयर में कुछ सेटिंग और वेरिएबल सेट करना ज़रूरी है, जैसा कि हम meta-interelectronix-visionfive में करते हैं।

• recipes-mender/mender-client/mender-client_%.bbappend: Mender सर्वर का URL जोड़ें

MENDER_SERVER_URL = "https://mender.interelectronix.com"

• recipes-bsp/u-boot/u-boot-visionfive_%.bbappend: नीचे दी गई लाइनें जोड़ें

MENDER_UBOOT_AUTO_CONFIGURE = "1"
BOOTENV_SIZE = "0x20000"

• recipes-bsp/u-boot-env/*: इस रेसिपी को डाउनलोड की गई ज़िप फ़ाइल से जोड़ें। इसमें दो uEnv-files हैं, जिनका इस्तेमाल रूट फ़ाइल सिस्टम में किया जाता है। uEnv_visionfive.txt का इस्तेमाल पार्टिशन A से बूट करते समय rootfs में किया जाता है और uEnv_visionfive3.txt का इस्तेमाल पार्टिशन B से बूट करते समय किया जाता है।

• recipes-core/images/vision-five-image-mender.bb: यह इमेज रेसिपी लें या फिर अपनी इमेज रेसिपी में 'u-boot-env' जोड़ें

IMAGE_INSTALL:append = " v4l-utils u-boot-env"

VisionFive - Mender - Yocto - भाग 3 में Mender के लिए u-boot सेटअप करने का तरीका देखें।

कॉपीराइट © 2022 Interelectronix e.K.
प्रोजेक्ट का सोर्स-कोड GPL-3.0 लाइसेंस के तहत लाइसेंस पर दिया जाता है।